三六豹子电脑机器人对赌完整技术脚本

三六豹子电脑机器人对赌脚本

[@三六]
{
#ACT
GOTO @DICE
BREAK

[@DICE]
╔════╗\
║<三六豹子>║   游戏开始前请认真阅读<说明书>.\
╠════╩══════════╦═════════╗\
║┏━━━┓┏━━━┓┏━━━┓║╔════╗　　　║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃╠╣<开始游戏/@DICE_2>║　╔═╩═╗\
║┃　　　┃┃　<●/SCOLOR=58>　┃┃<●　●/SCOLOR=58>┃║╚════╝　║<说明书/@DICE_HELP>║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║　╔════╗╚═╦═╝\
║┗━━━┛┗━━━┛┗━━━┛║　║<返回前页/@MAIN>╠══╝\
╚═══════════════╝　╚════╝\

[@DICE_2]
╔════╗\
║<返回首页/@MAIN>║\
╠════╩══════════╦════════╗\
║┏━━━┓┏━━━┓┏━━━┓║╔══╗　╔══╩══╗\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃╠╣<下注/@@INPUTINTEGER5>║　║一旦下注，║\
║┃　　　┃┃　<●/SCOLOR=58>　┃┃<●　●/SCOLOR=58>┃║╚══╝　║除非分出输║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║　╔══╗║赢，不然无║\
║┗━━━┛┗━━━┛┗━━━┛║　║<返回/@DICE>╠╣法收回注金║\
╚═══════════════╝　╚══╝╚═════╝\

[@@INPUTINTEGER5]
#IF
CHECKLEVELEX > 0
#ACT
DELAYGOTO 1 ~INPUTINTEGER5
[~INPUTINTEGER5]
#IF
LARGE M5 500000000
#ACT
MESSAGEBOX [提示]：你输入了<$STR(M5)>个元宝，玩的太大了，我只玩5亿以下的！
MOV M5 0
GOTO @DICE_2
BREAK

#IF
SMALL M5 100000
#ACT
MESSAGEBOX [提示]：下注金额最少10W个元宝。
MOV M5 0
GOTO @DICE_2
BREAK

#IF
CHECKGAMEGOLD > <$STR(M5)>
#SAY
╔════╗\
║<返回首页/@MAIN>║\
╠════╩══════════╦════════╗\
║┏━━━┓┏━━━┓┏━━━┓║╔══╗　╔══╩══╗\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃╠╣<开始/@DICE_3>║　║一旦开始后║\
║┃　　　┃┃　<●/SCOLOR=58>　┃┃<●　●/SCOLOR=58>┃║╚══╝　║除非分出输║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║　╔══╗║赢，不然无║\
║┗━━━┛┗━━━┛┗━━━┛║　║<返回/@DICE_2>╠╣法收回注金║\
╚═══════════════╝　╚══╝╚═════╝\
#ACT
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D6 0
MOV D7 0
MOV D8 0
MOV D9 0
BREAK
#ELSEACT
MESSAGEBOX [提示]：你身上没有<$STR(M5)>个元宝。
MOV M5 0
GOTO @DICE_2
BREAK

[@DICE_3]
#IF
CHECKGAMEGOLD > <$STR(M5)>
LARGE M5 0
#ACT
GAMEGOLD - <$STR(M5)>
SENDMSG 6 你支付了<$STR(M5)>元宝作为注金，当前还拥有<$GAMEGOLD>个元宝。
MOVR D0 5
INC D0 2
MOVR D1 5
INC D1 2
MOVR D2 5
INC D2 2
MOV D9 0
SUM D0 D1
SUM D2
PLAYDICE 3 @DICE_3_1
#SAY
\ \
╔═══════════════╗\
║┏━━━┓┏━━━┓┏━━━┓║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║╔══════════╗\
║┃　　　┃┃　<●/SCOLOR=58>　┃┃<●　●/SCOLOR=58>┃╠╣正在掷骰子请不要乱动║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║╚══════════╝\
║┗━━━┛┗━━━┛┗━━━┛║\
╚═══════════════╝本轮下注金额为：<$STR(M5)>元宝\

[@DICE_3_1]
#IF
LARGE D0 0
EQUAL D0 <$STR(D1)>
EQUAL D0 <$STR(D2)>
#ACT
SENDMSG 7 庄家掷出了　<$STR(D0)>　豹子，直接获胜。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK

#IF
LARGE D0 0
EQUAL D0 <$STR(D1)>
#ACT
MOV D3 <$STR(D2)>
MOV D0 0
MOV D1 0
MOV D2 0
MOV D8 0
MOV D9 0
GOTO @DICE_3_3
BREAK

#IF
LARGE D0 0
EQUAL D0 <$STR(D2)>
#ACT
MOV D3 <$STR(D1)>
MOV D0 0
MOV D1 0
MOV D2 0
MOV D8 0
MOV D9 0
GOTO @DICE_3_3
BREAK

#IF
LARGE D0 0
EQUAL D1 <$STR(D2)>
#ACT
MOV D3 <$STR(D0)>
MOV D0 0
MOV D1 0
MOV D2 0
MOV D8 0
MOV D9 0
GOTO @DICE_3_3
BREAK

#IF
LARGE D0 0
EQUAL D9 15
#ACT
SENDMSG 7 庄家掷出了四、五、六通杀，直接获胜。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK

#IF
LARGE D0 0
EQUAL D9 6
#ACT
GAMEGOLD + <$STR(M5)>
GAMEGOLD + <$STR(M5)>
SENDMSG 7 庄家掷出了一、二、三通赔，你赢得了<$STR(M5)>个元宝。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK
#ELSEACT
MOV D8 1
GOTO @DICE_3_2
BREAK

[@DICE_3_2]
#IF
EQUAL D8 1
#ACT
SENDMSG 6 庄家刚才掷的骰子没有出点数，现在正在重新掷骰子！
MOVR D0 5
INC D0 2
MOVR D1 5
INC D1 2
MOVR D2 5
INC D2 2
MOV D9 0
SUM D0 D1
SUM D2
PLAYDICE 3 @DICE_3_1
#SAY
\ \
╔═══════════════╗\
║┏━━━┓┏━━━┓┏━━━┓║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║╔══════════╗\
║┃　　　┃┃　<●/SCOLOR=58>　┃┃<●　●/SCOLOR=58>┃╠╣正在掷骰子请不要乱动║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║╚══════════╝\
║┗━━━┛┗━━━┛┗━━━┛║\
╚═══════════════╝本轮下注金额为：<$STR(M5)>元宝\
#ELSEACT
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK

[@DICE_3_3]
#IF
EQUAL D3 1
#ACT
GAMEGOLD + <$STR(M5)>
GAMEGOLD + <$STR(M5)>
SENDMSG 7 庄家掷出了幺屁眼，你赢得了<$STR(M5)>个元宝。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK

#IF
EQUAL D3 6
#ACT
SENDMSG 7 庄家掷出了大六，直接获胜。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK
#ELSESAY
╔════╗\
║<返回首页/@MAIN>║\
╠════╩══════════╗　　　　　　　　╔══╗\
║┏━━━┓┏━━━┓┏━━━┓║　　　　　　　　║<开始/@DICE_3_4>║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║╔═══════╩╦═╝\
║┃　　　┃┃　<●/SCOLOR=58>　┃┃<●　●/SCOLOR=58>┃╠╣庄家掷出了　<$STR(D3)> 点║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║║现在轮到你来掷了║\
║┗━━━┛┗━━━┛┗━━━┛║╚════════╝\
╚═══════════════╝本轮下注金额为：<$STR(M5)>元宝\

[@DICE_3_4]
#IF
LARGE D3 1
#ACT
MOVR D0 6
INC D0 1
MOVR D1 6
INC D1 1
MOVR D2 6
INC D2 1
MOV D9 0
SUM D0 D1
SUM D2
PLAYDICE 3 @DICE_3_5
#SAY
\ \
╔═══════════════╗\
║┏━━━┓┏━━━┓┏━━━┓║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║╔══════════╗\
║┃　　　┃┃　<●/SCOLOR=58>　┃┃<●　●/SCOLOR=58>┃╠╣正在掷骰子请不要乱动║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║╚══════════╝\
║┗━━━┛┗━━━┛┗━━━┛║\
╚═══════════════╝本轮下注金额为：<$STR(M5)>元宝\

[@DICE_3_5]
#IF
LARGE D3 0
EQUAL D0 <$STR(D1)>
EQUAL D0 <$STR(D2)>
#ACT
GAMEGOLD + <$STR(M5)>
GAMEGOLD + <$STR(M5)>
SENDMSG 7 你掷出了　<$STR(D0)>　豹子，你赢得了<$STR(M5)>个元宝。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK

#IF
LARGE D0 0
EQUAL D0 <$STR(D1)>
#ACT
MOV D9 <$STR(D2)>
GOTO @DICE_3_6
BREAK

#IF
LARGE D0 0
EQUAL D0 <$STR(D2)>
#ACT
MOV D9 <$STR(D1)>
GOTO @DICE_3_6
BREAK

#IF
LARGE D0 0
EQUAL D1 <$STR(D2)>
#ACT
MOV D9 <$STR(D0)>
GOTO @DICE_3_6
BREAK

#IF
EQUAL D9 15
#ACT
GAMEGOLD + <$STR(M5)>
GAMEGOLD + <$STR(M5)>
SENDMSG 7 你掷出了四、五、六，你赢得了<$STR(M5)>个元宝。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK

#IF
EQUAL D9 6
#ACT
SENDMSG 7 你掷出了一、二、三通赔，你输了本局。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK
#ELSEACT
MOV D8 2
GOTO @DICE_3_7
BREAK

[@DICE_3_6]
#IF
LARGE D3 1
LARGE D3 <$STR(D9)>
#ACT
SENDMSG 7 你掷出了<$STR(D9)>点，庄家是<$STR(D3)>点，你输了。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK

#IF
LARGE D3 1
SMALL D3 <$STR(D9)>
#ACT
GAMEGOLD + <$STR(M5)>
GAMEGOLD + <$STR(M5)>
SENDMSG 7 你掷出了<$STR(D9)>点，庄家是<$STR(D3)>点，你赢得了<$STR(M5)>个元宝。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK

#IF
LARGE D3 1
EQUAL D3 <$STR(D9)>
#ACT
GAMEGOLD + <$STR(M5)>
SENDMSG 7 你掷出了<$STR(D9)>点，庄家是<$STR(D3)>点，你们和了。
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK
#ELSEACT
GOTO @DICE
BREAK

[@DICE_3_7]
#IF
EQUAL D8 2
#ACT
SENDMSG 6 你刚才掷的骰子没有出点数，现在正在重新掷骰子！
MOVR D0 6
INC D0 1
MOVR D1 6
INC D1 1
MOVR D2 6
INC D2 1
MOV D9 0
SUM D0 D1
SUM D2
PLAYDICE 3 @DICE_3_5
#SAY
\ \
╔═══════════════╗\
║┏━━━┓┏━━━┓┏━━━┓║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║╔══════════╗\
║┃　　　┃┃　<●/SCOLOR=58>　┃┃<●　●/SCOLOR=58>┃╠╣正在掷骰子请不要乱动║\
║┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃┃<●　●/SCOLOR=58>┃║╚══════════╝\
║┗━━━┛┗━━━┛┗━━━┛║\
╚═══════════════╝本轮下注金额为：<$STR(M5)>元宝\
#ELSEACT
MOV D0 0
MOV D1 0
MOV D2 0
MOV D3 0
MOV D8 0
MOV D9 0
MOV M5 0
GOTO @DICE
BREAK

[@DICE_HELP]
首先你必须有元宝来下注，1注10W个元宝，最多5000注。然后由我开\
始掷骰子，如果掷出直接赢的点数，那么我直接赢得你的注金。如\
果掷出直接输的点数，那么你直接赢得注金。如果是其它点数，那\
么就轮到你来掷骰子了，如果你掷的点数比我小，那么我赢，如果\
比我大，你就赢。一样大的话就算和局。\
<点击查看骰子点数大小示例表/@DICE_HELP_1>\
<我知道规则可以开始了/@DICE_2>\
<返回前页/@DICE>\
<关闭/@EXIT>\

[@DICE_HELP_1]
╔┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄╗\
┊直接赢的点数为：<豹子>（<三个骰子点数一样/SCOLOR=250>）　　　　　　　┊\
┊　　　　　　　　<四五六通杀>（<骰子中包含4、5、6三点/SCOLOR=250>）　 ┊\
┊　　　　　　　　<大六>（<两个点数相同，另外一个点数为六/SCOLOR=250>）┊\
┊　　　　　　　　　　　　　　　　　　　　　　　　　　　┊\
┊直接输的点数为：<一二三通赔>（<骰子中包含1、2、3三点/SCOLOR=250>）　 ┊\
┊　　　　　　　　<幺屁眼>（<两个点数相同，另一个点数为一/SCOLOR=250>）┊\
┊　　　　　　　　　　　　　　　　　　　　<下一页/@DICE_HELP_2>　<返回/@DICE_HELP>　┊\
╚┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄╝\

[@DICE_HELP_2]
╔┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄╗\
┊其它点数按大小为：<五点>（<两个点数相同，另一个点数为五/SCOLOR=250>）┊\
┊　　　　　　　　　<四点>（<两个点数相同，另一个点数为四/SCOLOR=250>）┊\
┊　　　　　　　　　<三点>（<两个点数相同，另一个点数为三/SCOLOR=250>）┊\
┊　　　　　　　　　<二点>（<两个点数相同，另一个点数为二/SCOLOR=250>）┊\
┊　　　　　　　　　　　　　　　　　　　　　　　　　　　┊\
┊如果掷出骰子的三个点数全不相同，那么重新掷，直到掷出点┊\
┊数为止。　　　　　　　　　　　　　<前一页/@DICE_HELP_1>　<返回/@DICE_HELP>　<关闭/@EXIT>　┊\
╚┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄┄╝\

[@ISINFILTERLIST]
#ACT
MESSAGEBOX [错误]：输入数据中包含了非法字符,请重新编辑!
}